dlaorhr_col_getrfnp2()

recursive subroutine dlaorhr_col_getrfnp2	(	integer	M,
		integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( * )	D,
		integer	INFO
	)

DLAORHR_COL_GETRFNP2

Download DLAORHR_GETRF2NP + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DLAORHR_COL_GETRFNP2 computes the modified LU factorization without
 pivoting of a real general M-by-N matrix A. The factorization has
 the form:

     A - S = L * U,

 where:
    S is a m-by-n diagonal sign matrix with the diagonal D, so that
    D(i) = S(i,i), 1 <= i <= min(M,N). The diagonal D is constructed
    as D(i)=-SIGN(A(i,i)), where A(i,i) is the value after performing
    i-1 steps of Gaussian elimination. This means that the diagonal
    element at each step of "modified" Gaussian elimination is at
    least one in absolute value (so that division-by-zero not
    possible during the division by the diagonal element);

    L is a M-by-N lower triangular matrix with unit diagonal elements
    (lower trapezoidal if M > N);

    and U is a M-by-N upper triangular matrix
    (upper trapezoidal if M < N).

 This routine is an auxiliary routine used in the Householder
 reconstruction routine DORHR_COL. In DORHR_COL, this routine is
 applied to an M-by-N matrix A with orthonormal columns, where each
 element is bounded by one in absolute value. With the choice of
 the matrix S above, one can show that the diagonal element at each
 step of Gaussian elimination is the largest (in absolute value) in
 the column on or below the diagonal, so that no pivoting is required
 for numerical stability [1].

 For more details on the Householder reconstruction algorithm,
 including the modified LU factorization, see [1].

 This is the recursive version of the LU factorization algorithm.
 Denote A - S by B. The algorithm divides the matrix B into four
 submatrices:

        [  B11 | B12  ]  where B11 is n1 by n1,
    B = [ --&mdash;|--&mdash; ]        B21 is (m-n1) by n1,
        [  B21 | B22  ]        B12 is n1 by n2,
                               B22 is (m-n1) by n2,
                               with n1 = min(m,n)/2, n2 = n-n1.


 The subroutine calls itself to factor B11, solves for B21,
 solves for B12, updates B22, then calls itself to factor B22.

 For more details on the recursive LU algorithm, see [2].

 DLAORHR_COL_GETRFNP2 is called to factorize a block by the blocked
 routine DLAORHR_COL_GETRFNP, which uses blocked code calling
is self-sufficient and can be used without DLAORHR_COL_GETRFNP.

 [1] "Reconstructing Householder vectors from tall-skinny QR",
     G. Ballard, J. Demmel, L. Grigori, M. Jacquelin, H.D. Nguyen,
     E. Solomonik, J. Parallel Distrib. Comput.,
     vol. 85, pp. 3-31, 2015.

 [2] "Recursion leads to automatic variable blocking for dense linear
     algebra algorithms", F. Gustavson, IBM J. of Res. and Dev.,
     vol. 41, no. 6, pp. 737-755, 1997.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the M-by-N matrix to be factored. On exit, the factors L and U from the factorization A-S=L*U; the unit diagonal elements of L are not stored.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	D	D is DOUBLE PRECISION array, dimension min(M,N) The diagonal elements of the diagonal M-by-N sign matrix S, D(i) = S(i,i), where 1 <= i <= min(M,N). The elements can be only plus or minus one.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2019

Contributors:

 November 2019, Igor Kozachenko,
                Computer Science Division,
                University of California, Berkeley

Definition at line 169 of file dlaorhr_col_getrfnp2.f.

      IMPLICIT NONE
*
*  -- LAPACK computational routine (version 3.9.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2019
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), D( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   SFMIN
      INTEGER            I, IINFO, N1, N2
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dscal, dtrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dsign, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLAORHR_COL_GETRFNP2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( m, n ).EQ.0 )
     $   RETURN
 
      IF ( m.EQ.1 ) THEN
*
*        One row case, (also recursion termination case),
*        use unblocked code
*
*        Transfer the sign
*
         d( 1 ) = -dsign( one, a( 1, 1 ) )
*
*        Construct the row of U
*
         a( 1, 1 ) = a( 1, 1 ) - d( 1 )
*
      ELSE IF( n.EQ.1 ) THEN
*
*        One column case, (also recursion termination case),
*        use unblocked code
*
*        Transfer the sign
*
         d( 1 ) = -dsign( one, a( 1, 1 ) )
*
*        Construct the row of U
*
         a( 1, 1 ) = a( 1, 1 ) - d( 1 )
*
*        Scale the elements 2:M of the column
*
*        Determine machine safe minimum
*
         sfmin = dlamch('S')
*
*        Construct the subdiagonal elements of L
*
         IF( abs( a( 1, 1 ) ) .GE. sfmin ) THEN
            CALL dscal( m-1, one / a( 1, 1 ), a( 2, 1 ), 1 )
         ELSE
            DO i = 2, m
               a( i, 1 ) = a( i, 1 ) / a( 1, 1 )
            END DO
         END IF
*
      ELSE
*
*        Divide the matrix B into four submatrices
*
         n1 = min( m, n ) / 2
         n2 = n-n1
 
*
*        Factor B11, recursive call
*
         CALL dlaorhr_col_getrfnp2( n1, n1, a, lda, d, iinfo )
*
*        Solve for B21
*
         CALL dtrsm( 'R', 'U', 'N', 'N', m-n1, n1, one, a, lda,
     $               a( n1+1, 1 ), lda )
*
*        Solve for B12
*
         CALL dtrsm( 'L', 'L', 'N', 'U', n1, n2, one, a, lda,
     $               a( 1, n1+1 ), lda )
*
*        Update B22, i.e. compute the Schur complement
*        B22 := B22 - B21*B12
*
         CALL dgemm( 'N', 'N', m-n1, n2, n1, -one, a( n1+1, 1 ), lda,
     $               a( 1, n1+1 ), lda, one, a( n1+1, n1+1 ), lda )
*
*        Factor B22, recursive call
*
         CALL dlaorhr_col_getrfnp2( m-n1, n2, a( n1+1, n1+1 ), lda,
     $                              d( n1+1 ), iinfo )
*
      END IF
      RETURN
*
*     End of DLAORHR_COL_GETRFNP2
*

Here is the call graph for this function:

Here is the caller graph for this function: