cunbdb2.f

Go to the documentation of this file.

*> \brief \b CUNBDB2
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CUNBDB2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunbdb2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunbdb2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunbdb2.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CUNBDB2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
*                           TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LWORK, M, P, Q, LDX11, LDX21
*       ..
*       .. Array Arguments ..
*       REAL               PHI(*), THETA(*)
*       COMPLEX            TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
*      $                   X11(LDX11,*), X21(LDX21,*)
*       ..
*
*
*> \par Purpose:
*  =============
*>
*>\verbatim
*>
*> CUNBDB2 simultaneously bidiagonalizes the blocks of a tall and skinny
*> matrix X with orthonomal columns:
*>
*>                            [ B11 ]
*>      [ X11 ]   [ P1 |    ] [  0  ]
*>      [-----] = [---------] [-----] Q1**T .
*>      [ X21 ]   [    | P2 ] [ B21 ]
*>                            [  0  ]
*>
*> X11 is P-by-Q, and X21 is (M-P)-by-Q. P must be no larger than M-P,
*> Q, or M-Q. Routines CUNBDB1, CUNBDB3, and CUNBDB4 handle cases in
*> which P is not the minimum dimension.
*>
*> The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
*> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
*> Householder vectors.
*>
*> B11 and B12 are P-by-P bidiagonal matrices represented implicitly by
*> angles THETA, PHI.
*>
*>\endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>           The number of rows X11 plus the number of rows in X21.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>           The number of rows in X11. 0 <= P <= min(M-P,Q,M-Q).
*> \endverbatim
*>
*> \param[in] Q
*> \verbatim
*>          Q is INTEGER
*>           The number of columns in X11 and X21. 0 <= Q <= M.
*> \endverbatim
*>
*> \param[in,out] X11
*> \verbatim
*>          X11 is COMPLEX array, dimension (LDX11,Q)
*>           On entry, the top block of the matrix X to be reduced. On
*>           exit, the columns of tril(X11) specify reflectors for P1 and
*>           the rows of triu(X11,1) specify reflectors for Q1.
*> \endverbatim
*>
*> \param[in] LDX11
*> \verbatim
*>          LDX11 is INTEGER
*>           The leading dimension of X11. LDX11 >= P.
*> \endverbatim
*>
*> \param[in,out] X21
*> \verbatim
*>          X21 is COMPLEX array, dimension (LDX21,Q)
*>           On entry, the bottom block of the matrix X to be reduced. On
*>           exit, the columns of tril(X21) specify reflectors for P2.
*> \endverbatim
*>
*> \param[in] LDX21
*> \verbatim
*>          LDX21 is INTEGER
*>           The leading dimension of X21. LDX21 >= M-P.
*> \endverbatim
*>
*> \param[out] THETA
*> \verbatim
*>          THETA is REAL array, dimension (Q)
*>           The entries of the bidiagonal blocks B11, B21 are defined by
*>           THETA and PHI. See Further Details.
*> \endverbatim
*>
*> \param[out] PHI
*> \verbatim
*>          PHI is REAL array, dimension (Q-1)
*>           The entries of the bidiagonal blocks B11, B21 are defined by
*>           THETA and PHI. See Further Details.
*> \endverbatim
*>
*> \param[out] TAUP1
*> \verbatim
*>          TAUP1 is COMPLEX array, dimension (P)
*>           The scalar factors of the elementary reflectors that define
*>           P1.
*> \endverbatim
*>
*> \param[out] TAUP2
*> \verbatim
*>          TAUP2 is COMPLEX array, dimension (M-P)
*>           The scalar factors of the elementary reflectors that define
*>           P2.
*> \endverbatim
*>
*> \param[out] TAUQ1
*> \verbatim
*>          TAUQ1 is COMPLEX array, dimension (Q)
*>           The scalar factors of the elementary reflectors that define
*>           Q1.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>           The dimension of the array WORK. LWORK >= M-Q.
*>
*>           If LWORK = -1, then a workspace query is assumed; the routine
*>           only calculates the optimal size of the WORK array, returns
*>           this value as the first entry of the WORK array, and no error
*>           message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>           = 0:  successful exit.
*>           < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*>
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date July 2012
*
*> \ingroup complexOTHERcomputational
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The upper-bidiagonal blocks B11, B21 are represented implicitly by
*>  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
*>  in each bidiagonal band is a product of a sine or cosine of a THETA
*>  with a sine or cosine of a PHI. See [1] or CUNCSD for details.
*>
*>  P1, P2, and Q1 are represented as products of elementary reflectors.
*>  See CUNCSD2BY1 for details on generating P1, P2, and Q1 using CUNGQR
*>  and CUNGLQ.
*> \endverbatim
*
*> \par References:
*  ================
*>
*>  [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
*>      Algorithms, 50(1):33-65, 2009.
*>
*  =====================================================================
      SUBROUTINE cunbdb2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
     $                    TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine (version 3.8.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     July 2012
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LWORK, M, P, Q, LDX11, LDX21
*     ..
*     .. Array Arguments ..
      REAL               PHI(*), THETA(*)
      COMPLEX            TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
     $                   x11(ldx11,*), x21(ldx21,*)
*     ..
*
*  ====================================================================
*
*     .. Parameters ..
      COMPLEX            NEGONE, ONE
      parameter( negone = (-1.0e0,0.0e0),
     $                     one = (1.0e0,0.0e0) )
*     ..
*     .. Local Scalars ..
      REAL               C, S
      INTEGER            CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
     $                   lworkmin, lworkopt
      LOGICAL            LQUERY
*     ..
*     .. External Subroutines ..
      EXTERNAL           clarf, clarfgp, cunbdb5, csrot, cscal, clacgv,
     $                   xerbla
*     ..
*     .. External Functions ..
      REAL               SCNRM2
      EXTERNAL           scnrm2
*     ..
*     .. Intrinsic Function ..
      INTRINSIC          atan2, cos, max, sin, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test input arguments
*
      info = 0
      lquery = lwork .EQ. -1
*
      IF( m .LT. 0 ) THEN
         info = -1
      ELSE IF( p .LT. 0 .OR. p .GT. m-p ) THEN
         info = -2
      ELSE IF( q .LT. 0 .OR. q .LT. p .OR. m-q .LT. p ) THEN
         info = -3
      ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
         info = -5
      ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
         info = -7
      END IF
*
*     Compute workspace
*
      IF( info .EQ. 0 ) THEN
         ilarf = 2
         llarf = max( p-1, m-p, q-1 )
         iorbdb5 = 2
         lorbdb5 = q-1
         lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
         lworkmin = lworkopt
         work(1) = lworkopt
         IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
           info = -14
         END IF
      END IF
      IF( info .NE. 0 ) THEN
         CALL xerbla( 'CUNBDB2', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Reduce rows 1, ..., P of X11 and X21
*
      DO i = 1, p
*
         IF( i .GT. 1 ) THEN
            CALL csrot( q-i+1, x11(i,i), ldx11, x21(i-1,i), ldx21, c,
     $                  s )
         END IF
         CALL clacgv( q-i+1, x11(i,i), ldx11 )
         CALL clarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
         c = real( x11(i,i) )
         x11(i,i) = one
         CALL clarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
     $               x11(i+1,i), ldx11, work(ilarf) )
         CALL clarf( 'R', m-p-i+1, q-i+1, x11(i,i), ldx11, tauq1(i),
     $               x21(i,i), ldx21, work(ilarf) )
         CALL clacgv( q-i+1, x11(i,i), ldx11 )
         s = sqrt( scnrm2( p-i, x11(i+1,i), 1 )**2
     $           + scnrm2( m-p-i+1, x21(i,i), 1 )**2 )
         theta(i) = atan2( s, c )
*
         CALL cunbdb5( p-i, m-p-i+1, q-i, x11(i+1,i), 1, x21(i,i), 1,
     $                 x11(i+1,i+1), ldx11, x21(i,i+1), ldx21,
     $                 work(iorbdb5), lorbdb5, childinfo )
         CALL cscal( p-i, negone, x11(i+1,i), 1 )
         CALL clarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
         IF( i .LT. p ) THEN
            CALL clarfgp( p-i, x11(i+1,i), x11(i+2,i), 1, taup1(i) )
            phi(i) = atan2( real( x11(i+1,i) ), real( x21(i,i) ) )
            c = cos( phi(i) )
            s = sin( phi(i) )
            x11(i+1,i) = one
            CALL clarf( 'L', p-i, q-i, x11(i+1,i), 1, conjg(taup1(i)),
     $                  x11(i+1,i+1), ldx11, work(ilarf) )
         END IF
         x21(i,i) = one
         CALL clarf( 'L', m-p-i+1, q-i, x21(i,i), 1, conjg(taup2(i)),
     $               x21(i,i+1), ldx21, work(ilarf) )
*
      END DO
*
*     Reduce the bottom-right portion of X21 to the identity matrix
*
      DO i = p + 1, q
         CALL clarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
         x21(i,i) = one
         CALL clarf( 'L', m-p-i+1, q-i, x21(i,i), 1, conjg(taup2(i)),
     $               x21(i,i+1), ldx21, work(ilarf) )
      END DO
*
      RETURN
*
*     End of CUNBDB2
*
      END