srzt02()

real function srzt02	(	integer	M,
		integer	N,
		real, dimension( lda, * )	AF,
		integer	LDA,
		real, dimension( * )	TAU,
		real, dimension( lwork )	WORK,
		integer	LWORK
	)

SRZT02

Purpose:

 SRZT02 returns
      || I - Q'*Q || / ( M * eps)
 where the matrix Q is defined by the Householder transformations
 generated by STZRZF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix AF.
[in]	N	N is INTEGER The number of columns of the matrix AF.
[in]	AF	AF is REAL array, dimension (LDA,N) The output of STZRZF.
[in]	LDA	LDA is INTEGER The leading dimension of the array AF.
[in]	TAU	TAU is REAL array, dimension (M) Details of the Householder transformations as returned by STZRZF.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER length of WORK array. LWORK >= N*N+N*NB.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 93 of file srzt02.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               AF( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO
*     ..
*     .. Local Arrays ..
      REAL               RWORK( 1 )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, sormrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Executable Statements ..
*
      srzt02 = zero
*
      IF( lwork.LT.n*n+n ) THEN
         CALL xerbla( 'SRZT02', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     Q := I
*
      CALL slaset( 'Full', n, n, zero, one, work, n )
*
*     Q := P(1) * ... * P(m) * Q
*
      CALL sormrz( 'Left', 'No transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := P(m) * ... * P(1) * Q
*
      CALL sormrz( 'Left', 'Transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := Q - I
*
      DO 10 i = 1, n
         work( ( i-1 )*n+i ) = work( ( i-1 )*n+i ) - one
   10 CONTINUE
*
      srzt02 = slange( 'One-norm', n, n, work, n, rwork ) /
     $         ( slamch( 'Epsilon' )*real( max( m, n ) ) )
      RETURN
*
*     End of SRZT02
*

Here is the call graph for this function: