drzt02()

double precision function drzt02	(	integer	M,
		integer	N,
		double precision, dimension( lda, * )	AF,
		integer	LDA,
		double precision, dimension( * )	TAU,
		double precision, dimension( lwork )	WORK,
		integer	LWORK
	)

DRZT02

Purpose:

 DRZT02 returns
      || I - Q'*Q || / ( M * eps)
 where the matrix Q is defined by the Householder transformations
 generated by DTZRZF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix AF.
[in]	N	N is INTEGER The number of columns of the matrix AF.
[in]	AF	AF is DOUBLE PRECISION array, dimension (LDA,N) The output of DTZRZF.
[in]	LDA	LDA is INTEGER The leading dimension of the array AF.
[in]	TAU	TAU is DOUBLE PRECISION array, dimension (M) Details of the Householder transformations as returned by DTZRZF.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER length of WORK array. LWORK >= N*N+N*NB.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 93 of file drzt02.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AF( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlaset, dormrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Executable Statements ..
*
      drzt02 = zero
*
      IF( lwork.LT.n*n+n ) THEN
         CALL xerbla( 'DRZT02', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     Q := I
*
      CALL dlaset( 'Full', n, n, zero, one, work, n )
*
*     Q := P(1) * ... * P(m) * Q
*
      CALL dormrz( 'Left', 'No transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := P(m) * ... * P(1) * Q
*
      CALL dormrz( 'Left', 'Transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := Q - I
*
      DO 10 i = 1, n
         work( ( i-1 )*n+i ) = work( ( i-1 )*n+i ) - one
   10 CONTINUE
*
      drzt02 = dlange( 'One-norm', n, n, work, n, rwork ) /
     $         ( dlamch( 'Epsilon' )*dble( max( m, n ) ) )
      RETURN
*
*     End of DRZT02
*

Here is the call graph for this function: