dqrt17()

double precision function dqrt17	(	character	TRANS,
		integer	IRESID,
		integer	M,
		integer	N,
		integer	NRHS,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldx, * )	X,
		integer	LDX,
		double precision, dimension( ldb, * )	B,
		integer	LDB,
		double precision, dimension( ldb, * )	C,
		double precision, dimension( lwork )	WORK,
		integer	LWORK
	)

DQRT17

Purpose:

 DQRT17 computes the ratio

    || R'*op(A) ||/(||A||*alpha*max(M,N,NRHS)*eps)

 where R = op(A)*X - B, op(A) is A or A', and

    alpha = ||B|| if IRESID = 1 (zero-residual problem)
    alpha = ||R|| if IRESID = 2 (otherwise).

Parameters

[in]	TRANS	TRANS is CHARACTER*1 Specifies whether or not the transpose of A is used. = 'N': No transpose, op(A) = A. = 'T': Transpose, op(A) = A'.
[in]	IRESID	IRESID is INTEGER IRESID = 1 indicates zero-residual problem. IRESID = 2 indicates non-zero residual.
[in]	M	M is INTEGER The number of rows of the matrix A. If TRANS = 'N', the number of rows of the matrix B. If TRANS = 'T', the number of rows of the matrix X.
[in]	N	N is INTEGER The number of columns of the matrix A. If TRANS = 'N', the number of rows of the matrix X. If TRANS = 'T', the number of rows of the matrix B.
[in]	NRHS	NRHS is INTEGER The number of columns of the matrices X and B.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The m-by-n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= M.
[in]	X	X is DOUBLE PRECISION array, dimension (LDX,NRHS) If TRANS = 'N', the n-by-nrhs matrix X. If TRANS = 'T', the m-by-nrhs matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. If TRANS = 'N', LDX >= N. If TRANS = 'T', LDX >= M.
[in]	B	B is DOUBLE PRECISION array, dimension (LDB,NRHS) If TRANS = 'N', the m-by-nrhs matrix B. If TRANS = 'T', the n-by-nrhs matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. If TRANS = 'N', LDB >= M. If TRANS = 'T', LDB >= N.
[out]	C	C is DOUBLE PRECISION array, dimension (LDB,NRHS)
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= NRHS*(M+N).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 152 of file dqrt17.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            IRESID, LDA, LDB, LDX, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), C( LDB, * ),
     $                   WORK( LWORK ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, ISCL, NCOLS, NROWS
      DOUBLE PRECISION   BIGNUM, ERR, NORMA, NORMB, NORMRS, SMLNUM
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           lsame, dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy, dlascl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Executable Statements ..
*
      dqrt17 = zero
*
      IF( lsame( trans, 'N' ) ) THEN
         nrows = m
         ncols = n
      ELSE IF( lsame( trans, 'T' ) ) THEN
         nrows = n
         ncols = m
      ELSE
         CALL xerbla( 'DQRT17', 1 )
         RETURN
      END IF
*
      IF( lwork.LT.ncols*nrhs ) THEN
         CALL xerbla( 'DQRT17', 13 )
         RETURN
      END IF
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 ) THEN
         RETURN
      END IF
*
      norma = dlange( 'One-norm', m, n, a, lda, rwork )
      smlnum = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      bignum = one / smlnum
      iscl = 0
*
*     compute residual and scale it
*
      CALL dlacpy( 'All', nrows, nrhs, b, ldb, c, ldb )
      CALL dgemm( trans, 'No transpose', nrows, nrhs, ncols, -one, a,
     $            lda, x, ldx, one, c, ldb )
      normrs = dlange( 'Max', nrows, nrhs, c, ldb, rwork )
      IF( normrs.GT.smlnum ) THEN
         iscl = 1
         CALL dlascl( 'General', 0, 0, normrs, one, nrows, nrhs, c, ldb,
     $                info )
      END IF
*
*     compute R'*A
*
      CALL dgemm( 'Transpose', trans, nrhs, ncols, nrows, one, c, ldb,
     $            a, lda, zero, work, nrhs )
*
*     compute and properly scale error
*
      err = dlange( 'One-norm', nrhs, ncols, work, nrhs, rwork )
      IF( norma.NE.zero )
     $   err = err / norma
*
      IF( iscl.EQ.1 )
     $   err = err*normrs
*
      IF( iresid.EQ.1 ) THEN
         normb = dlange( 'One-norm', nrows, nrhs, b, ldb, rwork )
         IF( normb.NE.zero )
     $      err = err / normb
      ELSE
         IF( normrs.NE.zero )
     $      err = err / normrs
      END IF
*
      dqrt17 = err / ( dlamch( 'Epsilon' )*dble( max( m, n, nrhs ) ) )
      RETURN
*
*     End of DQRT17
*

Here is the call graph for this function: