clatdf.f

Go to the documentation of this file.

*> \brief \b CLATDF uses the LU factorization of the n-by-n matrix computed by sgetc2 and computes a contribution to the reciprocal Dif-estimate.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CLATDF + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clatdf.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clatdf.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clatdf.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLATDF( IJOB, N, Z, LDZ, RHS, RDSUM, RDSCAL, IPIV,
*                          JPIV )
*
*       .. Scalar Arguments ..
*       INTEGER            IJOB, LDZ, N
*       REAL               RDSCAL, RDSUM
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * ), JPIV( * )
*       COMPLEX            RHS( * ), Z( LDZ, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLATDF computes the contribution to the reciprocal Dif-estimate
*> by solving for x in Z * x = b, where b is chosen such that the norm
*> of x is as large as possible. It is assumed that LU decomposition
*> of Z has been computed by CGETC2. On entry RHS = f holds the
*> contribution from earlier solved sub-systems, and on return RHS = x.
*>
*> The factorization of Z returned by CGETC2 has the form
*> Z = P * L * U * Q, where P and Q are permutation matrices. L is lower
*> triangular with unit diagonal elements and U is upper triangular.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] IJOB
*> \verbatim
*>          IJOB is INTEGER
*>          IJOB = 2: First compute an approximative null-vector e
*>              of Z using CGECON, e is normalized and solve for
*>              Zx = +-e - f with the sign giving the greater value of
*>              2-norm(x).  About 5 times as expensive as Default.
*>          IJOB .ne. 2: Local look ahead strategy where
*>              all entries of the r.h.s. b is chosen as either +1 or
*>              -1.  Default.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix Z.
*> \endverbatim
*>
*> \param[in] Z
*> \verbatim
*>          Z is COMPLEX array, dimension (LDZ, N)
*>          On entry, the LU part of the factorization of the n-by-n
*>          matrix Z computed by CGETC2:  Z = P * L * U * Q
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of the array Z.  LDA >= max(1, N).
*> \endverbatim
*>
*> \param[in,out] RHS
*> \verbatim
*>          RHS is COMPLEX array, dimension (N).
*>          On entry, RHS contains contributions from other subsystems.
*>          On exit, RHS contains the solution of the subsystem with
*>          entries according to the value of IJOB (see above).
*> \endverbatim
*>
*> \param[in,out] RDSUM
*> \verbatim
*>          RDSUM is REAL
*>          On entry, the sum of squares of computed contributions to
*>          the Dif-estimate under computation by CTGSYL, where the
*>          scaling factor RDSCAL (see below) has been factored out.
*>          On exit, the corresponding sum of squares updated with the
*>          contributions from the current sub-system.
*>          If TRANS = 'T' RDSUM is not touched.
*>          NOTE: RDSUM only makes sense when CTGSY2 is called by CTGSYL.
*> \endverbatim
*>
*> \param[in,out] RDSCAL
*> \verbatim
*>          RDSCAL is REAL
*>          On entry, scaling factor used to prevent overflow in RDSUM.
*>          On exit, RDSCAL is updated w.r.t. the current contributions
*>          in RDSUM.
*>          If TRANS = 'T', RDSCAL is not touched.
*>          NOTE: RDSCAL only makes sense when CTGSY2 is called by
*>          CTGSYL.
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N).
*>          The pivot indices; for 1 <= i <= N, row i of the
*>          matrix has been interchanged with row IPIV(i).
*> \endverbatim
*>
*> \param[in] JPIV
*> \verbatim
*>          JPIV is INTEGER array, dimension (N).
*>          The pivot indices; for 1 <= j <= N, column j of the
*>          matrix has been interchanged with column JPIV(j).
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date June 2016
*
*> \ingroup complexOTHERauxiliary
*
*> \par Further Details:
*  =====================
*>
*>  This routine is a further developed implementation of algorithm
*>  BSOLVE in [1] using complete pivoting in the LU factorization.
*
*> \par Contributors:
*  ==================
*>
*>     Bo Kagstrom and Peter Poromaa, Department of Computing Science,
*>     Umea University, S-901 87 Umea, Sweden.
*
*> \par References:
*  ================
*>
*>   [1]   Bo Kagstrom and Lars Westin,
*>         Generalized Schur Methods with Condition Estimators for
*>         Solving the Generalized Sylvester Equation, IEEE Transactions
*>         on Automatic Control, Vol. 34, No. 7, July 1989, pp 745-751.
*>
*>   [2]   Peter Poromaa,
*>         On Efficient and Robust Estimators for the Separation
*>         between two Regular Matrix Pairs with Applications in
*>         Condition Estimation. Report UMINF-95.05, Department of
*>         Computing Science, Umea University, S-901 87 Umea, Sweden,
*>         1995.
*
*  =====================================================================
      SUBROUTINE clatdf( IJOB, N, Z, LDZ, RHS, RDSUM, RDSCAL, IPIV,
     $                   JPIV )
*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2016
*
*     .. Scalar Arguments ..
      INTEGER            IJOB, LDZ, N
      REAL               RDSCAL, RDSUM
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), JPIV( * )
      COMPLEX            RHS( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            MAXDIM
      parameter( maxdim = 2 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J, K
      REAL               RTEMP, SCALE, SMINU, SPLUS
      COMPLEX            BM, BP, PMONE, TEMP
*     ..
*     .. Local Arrays ..
      REAL               RWORK( MAXDIM )
      COMPLEX            WORK( 4*MAXDIM ), XM( MAXDIM ), XP( MAXDIM )
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, ccopy, cgecon, cgesc2, classq, claswp,
     $                   cscal
*     ..
*     .. External Functions ..
      REAL               SCASUM
      COMPLEX            CDOTC
      EXTERNAL           scasum, cdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( ijob.NE.2 ) THEN
*
*        Apply permutations IPIV to RHS
*
         CALL claswp( 1, rhs, ldz, 1, n-1, ipiv, 1 )
*
*        Solve for L-part choosing RHS either to +1 or -1.
*
         pmone = -cone
         DO 10 j = 1, n - 1
            bp = rhs( j ) + cone
            bm = rhs( j ) - cone
            splus = one
*
*           Lockahead for L- part RHS(1:N-1) = +-1
*           SPLUS and SMIN computed more efficiently than in BSOLVE[1].
*
            splus = splus + real( cdotc( n-j, z( j+1, j ), 1, z( j+1,
     $              j ), 1 ) )
            sminu = real( cdotc( n-j, z( j+1, j ), 1, rhs( j+1 ), 1 ) )
            splus = splus*real( rhs( j ) )
            IF( splus.GT.sminu ) THEN
               rhs( j ) = bp
            ELSE IF( sminu.GT.splus ) THEN
               rhs( j ) = bm
            ELSE
*
*              In this case the updating sums are equal and we can
*              choose RHS(J) +1 or -1. The first time this happens we
*              choose -1, thereafter +1. This is a simple way to get
*              good estimates of matrices like Byers well-known example
*              (see [1]). (Not done in BSOLVE.)
*
               rhs( j ) = rhs( j ) + pmone
               pmone = cone
            END IF
*
*           Compute the remaining r.h.s.
*
            temp = -rhs( j )
            CALL caxpy( n-j, temp, z( j+1, j ), 1, rhs( j+1 ), 1 )
   10    CONTINUE
*
*        Solve for U- part, lockahead for RHS(N) = +-1. This is not done
*        In BSOLVE and will hopefully give us a better estimate because
*        any ill-conditioning of the original matrix is transferred to U
*        and not to L. U(N, N) is an approximation to sigma_min(LU).
*
         CALL ccopy( n-1, rhs, 1, work, 1 )
         work( n ) = rhs( n ) + cone
         rhs( n ) = rhs( n ) - cone
         splus = zero
         sminu = zero
         DO 30 i = n, 1, -1
            temp = cone / z( i, i )
            work( i ) = work( i )*temp
            rhs( i ) = rhs( i )*temp
            DO 20 k = i + 1, n
               work( i ) = work( i ) - work( k )*( z( i, k )*temp )
               rhs( i ) = rhs( i ) - rhs( k )*( z( i, k )*temp )
   20       CONTINUE
            splus = splus + abs( work( i ) )
            sminu = sminu + abs( rhs( i ) )
   30    CONTINUE
         IF( splus.GT.sminu )
     $      CALL ccopy( n, work, 1, rhs, 1 )
*
*        Apply the permutations JPIV to the computed solution (RHS)
*
         CALL claswp( 1, rhs, ldz, 1, n-1, jpiv, -1 )
*
*        Compute the sum of squares
*
         CALL classq( n, rhs, 1, rdscal, rdsum )
         RETURN
      END IF
*
*     ENTRY IJOB = 2
*
*     Compute approximate nullvector XM of Z
*
      CALL cgecon( 'I', n, z, ldz, one, rtemp, work, rwork, info )
      CALL ccopy( n, work( n+1 ), 1, xm, 1 )
*
*     Compute RHS
*
      CALL claswp( 1, xm, ldz, 1, n-1, ipiv, -1 )
      temp = cone / sqrt( cdotc( n, xm, 1, xm, 1 ) )
      CALL cscal( n, temp, xm, 1 )
      CALL ccopy( n, xm, 1, xp, 1 )
      CALL caxpy( n, cone, rhs, 1, xp, 1 )
      CALL caxpy( n, -cone, xm, 1, rhs, 1 )
      CALL cgesc2( n, z, ldz, rhs, ipiv, jpiv, scale )
      CALL cgesc2( n, z, ldz, xp, ipiv, jpiv, scale )
      IF( scasum( n, xp, 1 ).GT.scasum( n, rhs, 1 ) )
     $   CALL ccopy( n, xp, 1, rhs, 1 )
*
*     Compute the sum of squares
*
      CALL classq( n, rhs, 1, rdscal, rdsum )
      RETURN
*
*     End of CLATDF
*
      END